Get a list of files in VBA


There are two ways to get a list of files inside a folder with VBA. The first one is the Microsoft Scripting Library way, where the FileSystemObject is used. The second one is the "traditional" Dir command which returns a file each time the function is called.
'the scripting lib way
Public Function GetListOfFiles(path As String, ParamArray Extensions()) As String()
   Dim fs As New FileSystemObject
   Dim fld As Folder: Set fld = fs.GetFolder(path)
   Dim fl As file
   Dim list() As String, count As Long: count = 0
   
   For Each fl In fld.files
      Dim ext As String, extIncluded As Boolean, i As Long
      ext = fs.GetExtensionName(fl.name)
      
      extIncluded = False
      For i = 0 To UBound(Extensions)
         If LCase(ext) = LCase(Extensions(i)) Then
            extIncluded = True
            Exit For
         End If
      Next
      
      'If ext = "xls" Or ext = "xlsb" Or ext = "xlsx" Or ext = "xlsm" Then
      If extIncluded Then
         count = count + 1
         ReDim Preserve list(1 To count)
         list(count) = fl.path
      End If
   Next
   
   GetListOfFiles = list
End Function

If we want to avoid using the Microsoft Scripting Runtime, we may use the Dir command which seems to be convenient but only for small tasks.
Public Function GetListOfFiles(path As String, ParamArray Extensions()) As String()
   Dim list() As String, count As Long: count = 0
   
   If Right$(path, 1) <> "\" _
      Then path = path & "\"
   
   Dim iExt As Long
   For iExt = 0 To UBound(Extensions)
      Dim fl As String
      fl = Dir(path & "*." & Extensions(iExt))
      
      Do While Len(fl) > 0
         count = count + 1
         ReDim Preserve list(1 To count)
         list(count) = path & fl
        
         fl = Dir
      Loop
   Next
   
   GetListOfFiles = list
End Function

A sample of use follows where both functions may be used. The path may be given with or without a trailing slash. The extensions should be given without the period. To retrieve all files just pass * as the Extensions parameter. 
Public Sub test()
   Dim files() As String
   files = GetListOfFiles("D:\charts", "gif")
   Dim i As Long
   For i = 1 To UBound(files)
      Debug.Print files(i)
   Next
End Sub

Comments

Post a Comment

Popular posts from this blog

Write Unicode text using VBA

Image
There are some ways to create and access Unicode files using VBA. The most straightforward way is to use the Microsoft Scripting Runtime library. The two following ways may be used to open a file for write operations: 'the scripting lib way Dim fs As New FileSystemObject, txt As TextStream Dim pth As String : pth = "d:\data.txt" Set txt = fs.CreateTextFile(pth, True, True) ''alternative way to open the textfile 'Set txt = fs.OpenTextFile(pth, ForWriting, True, TristateTrue) 'to write simply write the following in Unicode txt.WriteLine "test text" If we want to avoid using the Microsoft Scripting Runtime, we may use the following code; we access the output file in binary mode and we manually convert text to Unicode: 'the manual way Open pth For Binary Access Write As #1 Dim buffer() as Byte : buffer = "test text" Put #1, , buffer Close #1
Read more

Calling Fortran intrinsic functions from Visual Basic

Image
There is a great way to call the Fortran intrinsic libraries from Visual Basic, without wrapping them to dynamic libraries. I have the Digital Fortran installed on my computer, so I found out one of the running DLLs which is the dforrt.dll and that contains the Fortran intrinsic libraries (which are used by the Digital compiler). I simply opened the DLL with the Depends program and I found out the name of the functions that are declared in the DLL file. Knowing that the tangent function is declared as DTAN in Fortran, I found out some functions and declared them in a Visual Basic module file like this: Public Declare Function DTAN# Lib "dforrt.dll" Alias "_FXDTAN" (x#) Public Declare Function DTAN5# Lib "dforrt.dll" Alias "_FXIDTAN" (x#) And here is a sample call: Const PI As Double = 3.14159265358979 'the tangent of PI/4 will return 1.0 Debug.Print DTAN(PI / 4) Of course the tangent function is an intrinsic one in Visual Basic. H...
Read more

Dictionary class extensions (CopyTo, Sort) (C#)

Image
It seems that are not any CopyTo and Sort functions in the Dictionary class that resides in the Systems.Collection.Generic namespace. The OrderBy extension method used by Linq is not very practical to me, because it does not return a dictionary object. Here is my extension method CopyTo, applicable to generic Dictionary objects, allowing to define a part of the dictionary: public static void CopyTo<T, V>(this Dictionary<T, V> source, Dictionary<T, V> target) { if (target == null) target = new Dictionary<T, V>(); foreach (KeyValuePair<T, V> entry in source) target.Add(entry.Key, entry.Value); } public static void CopyTo<T, V>(this Dictionary<T, V> source, Dictionary<T, V> target, int start) { if (target == null) target = new Dictionary<T, V>(); int iEntry = 0; foreach (KeyValuePair<T, V> entry in source) { if (iEntry++ >= start) target.Add(entry.Key, entry.Value); } } public static void CopyTo<T, V>(this Dicti...
Read more